***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 17, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SM5S33A-AU A K 
.param
+vc0 = 3.806e-10	vc1 = 6.076e-11		vc2 = 1.000		vc3 = 4.035e-11		vc4 = 1.822e-1
+tc1 = 3.721e-2		tc2 = 2.871e-2		tc3 = 2.101e-2		tc4 = 2.601e-2
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 6.008e-13	   n = 1.067		  rs = 3.692e-3
+ibv = 5.0e-3		 nbv = 1.0		  bv = 38.65
+ikf = 1.175e-0
***** capacitance parameter *****
+cjo = 5.041e-9		   m = 3.437e-1		  vj = 6.026e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.082		 xti = 3
+trs1 = -3.025e-4	trs2 = 1.675e-5		tikf = 2.0e-3
+tbv1 = 8.649e-4	tbv2 = -7.520e-7	
.ends SM5S33A-AU
*$
